[CodeAnalysis] - Copy to

Boa tarde Cláudia,

Assim como o SonarQube informa, essa é uma chamada de driver ISAM descontinuada, logo você precisa fazer essa exportação de outra forma, seria possível exportar no formato de CSV, assim como o SonarQube indica como solução.

Abaixo um exemplo de função bem genérico que exporta uma tabela qualquer para CSV:

#include "protheus.ch"

//-------------------------------------------------------------------
/*/{Protheus.doc} csvExprt
Efetua a exportação do alias recebido em um arquivo em formato CSV

@param cAlias Alias que será exportado
@param cFile Nome do arquivo que será gravado
@param cSeparator Separador do CSV, pode ser |, "," e ;...

@sample  U_csvExprt("SA1")
@author  Daniel Mendes
@version 1.0
@since   10/03/2020
/*/
//-------------------------------------------------------------------
user function csvExprt(cAlias, cFile, cSeparator)
local nRecNo as numeric
local nFields as numeric
local nLoop as numeric
local cLine as char
local nHandler as numeric
local cBreakLine as char

default cFile := cAlias + "_" + DtoS(Date()) + ".csv"

if File(cFile)
    UserException("O arquivo para exportação já existe")
endif

default cSeparator := ";"

nHandler := FCreate(cFile)
nRecNo := (cAlias)->(RecNo())
nFields := (cAlias)->(FCount())
cBreakLine := Chr(13) + Chr(10)
cLine := ""

for nLoop := 1 to nFields
    cLine += (cAlias)->(FieldName(nLoop)) + cSeparator
next

cLine := Left(cLine, Len(cLine) -1) + cBreakLine

FWrite(nHandler, cLine)

(cAlias)->(DBGoTop())

while !(cAlias)->(Eof())
    cLine := ""

    for nLoop := 1 to nFields
        cLine += cValToChar((cAlias)->(FieldGet(nLoop))) + cSeparator
    next

    cLine := Left(cLine, Len(cLine) -1) + cBreakLine

    FWrite(nHandler, cLine)

    (cAlias)->(DBSkip())
enddo

FClose(nHandler)

(cAlias)->(DBGoTo(nRecNo))

return

Bom dia. Não sei se vai ajudar no seu caso, mas tive um problema com o comando COPY TO.

Ao tentar copiar as informações de um select para um arquivo temporário via COPY TO ocorria o seguinte error log:

\servidor\protheus_data\system\scbzmh50.dtc: Ctree Error (Disk Manager) - Create - File Delete Error - File: \servidor\protheus_data\system\scbzmh50.dtc on

Implementei o seguinte trecho para substituição do COPY TO:

bGrava := {|| AEVAL(aStruct,{|X| &(uAlias+"->"+x[1] + " := " + cAlias+"->"+x[1]) }) }

DBEVAL({|| Iif((uAlias)->(reclock(uAlias,.T.)),(Eval(bGrava),(uAlias)->(MsUnLock())),Nil) })

Onde: - uAlias é o arquivo temporário - cAlias é o o select com os registros que irão popular o arquivo temporário

Espero que ajude.

Abs.