Validação alteração de campos MVC

Cirilo, eu já fiz isso em um grid MVC, não sei se o processo para um formulário MVC é o mesmo.

No método AddGrid da classe MpFormModel, o bloco de código bLinePre recebe alguns parâmetros para realizar essas tratativas. São eles:

• oModel = Objeto da classe FwFormGridModel.
  • nLine = Linha posicionada.
  • cAction = Ação que está sendo realizada, exemplo: DELETE, UNDELETE, SETVALUE, CANSETVALUE.
  • cIDField = Id do campo alterado.
  • xNewValue = Novo valor atribuído.
  • xValue = Valor atual do campo.

Exemplo:

oModel:AddGrid('ModelGrid','ModelMaster',oStruGrid,{ |oModel, nLine, cAction, cIDField, xNewValue, xValue| fVldField(oModel, nLine, cAction, cIDField, xNewValue, xValue) },/*bLinePost*/,/*bPre*/,/*bLinePost*/)

Static Function fVldField(oModel, nLine, cAction, cIDField, xNewValue, xValue)
Local lRet := .T.

    If(cAction == 'SETVALUE' .and. cIDField == 'ZRO_VALEXT')

        If((xValue - xNewValue) > oModel:GetValue('ZRO_SALDO'))

            lRet := .F.

            Help(,,'Ação não permitida!',,'A diminuição do Valor Extra iria negativar o saldo da verba!',1,0,,,,,,{'Não pode existir uma verba com saldo negativo.'})

        Endif

    Endif

Return(lRet)

Na documentação do método AddFields da MpFormModel, no bloco bPre (que seria o equivalente ao bLinePre do grid), não existe esse parâmetro xValue (valor atual), apenas o xNewValue (novo valor). Porém como ele te passa o objeto FwFormFieldsModel, acredito que você consiga consultar o conteúdo anterior através desse objeto.

Uma opção que precisei usar uma vez foi colocar uma validação no momento do MODELPOS (acredito que funciona também em outros momentos como FORMCOMMITTTSPRE) dentro do PE do MVC.

Eu recupero a informação que está no banco via query (um tcQuery simples) e comparava com o campo por fwFldGet.

Conforme a minha necessidade, eu retornava true/false, fazia validações, etc.

Mas, isso eu fazia para poucos campos, se forem muitos, acredito que não valha a pena. Acho que é válido o teste para a sua necessidade de qualquer forma.