Problema com X3_INIBRW - Browse Contas a Receber

Senhores, bom dia.

Fiz a seguinte função:


User Function TUR06M06()
    Local dRet      := CriaVar("E5_DTDISPO", .F.)
    Local cQry      := ""

    cQry += "SELECT TOP 1 E5_DTDISPO "
    cQry += "FROM "+RetSqlName("SE5")+" SE5 (NOLOCK) "
    cQry += "WHERE SE5.D_E_L_E_T_ = ' ' "
    cQry += "    AND E5_FILIAL = '"+SE1->E1_FILIAL+"' "
    cQry += "    AND E5_PREFIXO = '"+SE1->E1_PREFIXO+"' "
    cQry += "    AND E5_NUMERO = '"+SE1->E1_NUM+"' "
    cQry += "    AND E5_PARCELA = '"+SE1->E1_PARCELA+"' "
    cQry += "    AND E5_TIPO = '"+SE1->E1_TIPO+"' "
    cQry += "    AND E5_CLIENTE = '"+SE1->E1_CLIENTE+"' "
    cQry += "    AND E5_LOJA = '"+SE1->E1_LOJA+"' "
    cQry += "   ORDER BY E5_DATA"

    TcQuery cQry New Alias "QRYSE5"

    DbSelectArea("QRYSE5")
    QRYSE5->(dbGoTop())

    if !QRYSE5->(Eof())
        dRet := SToD(QRYSE5->E5_DTDISPO)
    endif

    QRYSE5->(DbCloSeArea())

Return dRet

Porém ao clicar em imprimir o browse na tela do contas a receber, está gerando o erro em anexo.

Valeu pela força.

advpl

criado 4 weeks ago
Helio Couto Vespaziano
2 pontos
editado 4 weeks ago

Anexos

erro.jpg

Você vai ver essas setas em qualquer página de pergunta. Com elas, você pode dizer se uma pergunta ou uma resposta foram relevantes ou não.
Edite sua pergunta ou resposta caso queira alterar ou adicionar detalhes.
Caso haja alguma dúvida sobre a pergunta, adicione um comentário. O espaço de respostas deve ser utilizado apenas para responder a pergunta.
Se o autor da pergunta marcar uma resposta como solucionada, esta marca aparecerá.
Clique aqui para mais detalhes sobre o funcionamento do TOTVS DevForum!

1 resposta

up 0 down
Olá,

Helio, talvez seja por conta da mudança da workarea corrente, tente restaurar a workarea corrente após sua query, talvez resolva o problema.

Você pode restaurar utilizando GetArea e RestArea ou apenas com as funções Alias e DbSelectArea, particularmente quando se trata apenas da workarea, eu prefiro utilizar as funções Alias e DbSelectArea, pois fica mais simples, leve e rápido, exemplo:
```
User Function TUR06M06() as date
    Local dRet as date
    Local cQry as character
    Local cArea as character

    cArea     := Alias() //Aqui poderia ser um GetArea
    dRet      := CriaVar("E5_DTDISPO", .F.)
    cQry      := ""

    cQry += "SELECT TOP 1 E5_DTDISPO "
    cQry += "FROM "+RetSqlName("SE5")+" SE5 (NOLOCK) "
    cQry += "WHERE SE5.D_E_L_E_T_ = ' ' "
    cQry += "    AND E5_FILIAL = '"+SE1->E1_FILIAL+"' "
    cQry += "    AND E5_PREFIXO = '"+SE1->E1_PREFIXO+"' "
    cQry += "    AND E5_NUMERO = '"+SE1->E1_NUM+"' "
    cQry += "    AND E5_PARCELA = '"+SE1->E1_PARCELA+"' "
    cQry += "    AND E5_TIPO = '"+SE1->E1_TIPO+"' "
    cQry += "    AND E5_CLIENTE = '"+SE1->E1_CLIENTE+"' "
    cQry += "    AND E5_LOJA = '"+SE1->E1_LOJA+"' "
    cQry += "   ORDER BY E5_DATA"

    TcQuery cQry New Alias "QRYSE5"

    DbSelectArea("QRYSE5")
    QRYSE5->(dbGoTop())

    if !QRYSE5->(Eof())
        dRet := SToD(QRYSE5->E5_DTDISPO)
    endif

    QRYSE5->(DbCloSeArea())

    dbSelectArea(cArea) //Aqui poderia ser um RestArea
Return dRet
```
Espero que resolva :D

Documentações:

https://tdn.totvs.com/display/tec/DBSelectArea

https://tdn.totvs.com/display/tec/Alias

https://tdn.totvs.com/pages/viewpage.action?pageId=24346925

https://tdn.totvs.com/pages/viewpage.action?pageId=24347058
- editar
- x
  
  grosseiro ou ofensivo pouco construtivo obsoleto outro...
  Motivo
- criado 4 weeks ago
  Daniel Mendes
  15792 pontos
Adicionar comentário

Caracteres restantes: 600
Quero acompanhar este tópico via email.

Comentário
Utilize formatação mini-Markdown: [link](http://exemplo.com) _italico_ **negrito** `codigo`.
Comentarios devem ter, no maximo, 600 caracteres. Se achar necessario, utilize links em vez de copiar código ou ainda edite sua pergunta/resposta para colocar mais informações

Problema com X3_INIBRW - Browse Contas a Receber

Comentário

1 resposta

Comentário

Não é a resposta que estava procurando? Procure outras perguntas com as tags advpl ou faça a sua própria pergunta.