Se alguma pergunta ou resposta lhe foi útil, não deixe de dar seu voto positivo!

Validar campo função SM0 retorna Código Filial

Olá Pessoal Boa tarde.

Tenho uma tela MVC modelo 3. Que preciso validar se o código de filial digitado no campo(ZZH_CODEMP) existe na tabela SM0.

Tentei fazer essa função, mas não sei como funciona essa tabela SM0.

User Function zEMP()

Local aArea := GetArea()

Local lRet := .T.

DbSelectArea("SM0")

SM0->(DbSetOrder(1))

SM0->(DbGoTop())

While SM0->(!Eof() .And. SM0->M0_CODFIL == "01")

IF SM0->(DbSeek(xFilial("SM0") + M->ZZH_CODEMP)) MsgAlert("Existe !!")

ELSE

MsgAlert("Não existe registro no campo Empresa com esse código")

ENDIF

SM0->(DbSkip())

EndDo

SM0->(DbCloseArea())

RestArea(aArea)

Return (lRet)

Alguém teria algum exemplo, vi que existe a função FWLoadSM0, mas não sei como usar nesse caso.

criado 02 de Jun de 2022
Eduarda Menezes
147 pontos
editado 02 de Jun de 2022

Você vai ver essas setas em qualquer página de pergunta. Com elas, você pode dizer se uma pergunta ou uma resposta foram relevantes ou não.
Edite sua pergunta ou resposta caso queira alterar ou adicionar detalhes.
Caso haja alguma dúvida sobre a pergunta, adicione um comentário. O espaço de respostas deve ser utilizado apenas para responder a pergunta.
Se o autor da pergunta marcar uma resposta como solucionada, esta marca aparecerá.
Clique aqui para mais detalhes sobre o funcionamento do TOTVS DevForum!

3 respostas

up 1 down
Boa tarde!

O campo ZZH_CODEMP se refere ao código da empresa (M0_CODIGO) ou da filial da empresa (M0_CODFIL)?

Você pode usar a classe FwSM0Util para busca da empresa/filial que deseja. Exemplo:
```
If(Len(FwSM0Util():GetSM0Data(M->ZZH_CODEMP)) == 0)

    Help(,,'Empresa não existe',,'O código da empresa digitado não existe na tabela SM0.',1,0,,,,,,{''})

EndIf
```
Lembrando que o método GetSM0Data recebe a empresa como primeiro parâmetro e filial como segundo parâmetro.

Em caso de dúvidas sobre como é a sua estrutura da SM0 e caso seu dicionário de dados estiver na system, basta abrir o arquivo sigamat.emp pelo APSDU. Este arquivo está dentro da pasta system do Protheus.
- editar
- x
  
  grosseiro ou ofensivo pouco construtivo obsoleto outro...
  Motivo
- criado 02 de Jun de 2022
  Giordano Trabach Xavier
  4066 pontos
- 0
  
  Olá Giordano, o campo ZZH_CODEMP se refere ao M0_CODFIL, Obrigada seu exemplo me deu ideia de como fazer.
  — Eduarda Menezes 06 de Jun de 2022
Adicionar comentário

Caracteres restantes: 600
Quero acompanhar este tópico via email.

Comentário
Utilize formatação mini-Markdown: [link](http://exemplo.com) _italico_ **negrito** `codigo`.
Comentarios devem ter, no maximo, 600 caracteres. Se achar necessario, utilize links em vez de copiar código ou ainda edite sua pergunta/resposta para colocar mais informações

Amigo acho que o programa abaixo faz o que você precisa. Realmente o melhor caminho é usando a função FWLoadSM0() para não mexer no SM0/Sigamat diretamente. Procurei se tinha alguma coisa padrão mas não encontrei, em alguns lugares vi usando diretamente a função ExistCpo('SM0',cEmpAnt+mv_par02,1), não considero uma boa opção porque vai desposicionar a tabela SM0.

#INCLUDE 'RWMake.ch'
#INCLUDE 'Totvs.ch'
#INCLUDE 'ParmType.ch'
#INCLUDE 'FWCommand.CH'

//#############################################################################
//##+==========+===========+=======+====================+======+============+##
//##|Programa  | VldFilial | Autor | Cirilo Rocha      | Data | 02/06/2022  |##
//##+==========+===========+=======+====================+======+============+##
//##|Desc.     | Função para validar se a filial passada existe no SM0      |##
//##+==========+==========+=================================================+##
//##| DATA     | ANALISTA | MANUTENÇÃO EFETUADA                             |##
//##+==========+==========+=================================================+##
//##|          |          |                                                 |##
//##|          |          |                                                 |##
//##|          |          |                                                 |##
//##+==========+==========+=================================================+##
//#############################################################################
User Function VldFilial(cFilVld);
                            AS Logical

    //Declaração de Variáveis----------------------------------------------------------------------
    Local aSM0        AS Array
    Local lRet        AS Logical
    Local nX        AS Numeric

    //Parametros da rotina-------------------------------------------------------------------------
    ParamType 0        VAR cFilVld        AS Character

    //Inicializa Variaveis-------------------------------------------------------------------------
    lRet    := .F.

    //Carrega informacoes das empresas -> posicoes #include 'FWCommand.CH'
    aSM0    := FWLoadSM0()

    For nX := 1 To Len( aSM0 )
        If     aSM0[nX][SM0_GRPEMP] == cEmpAnt .And. ;
            RTrim(aSM0[nX][SM0_CODFIL]) == RTrim(cFilVld)

            lRet    := .T.
            Exit
        EndIf
    Next

    If .Not. lRet
        //MVC precisa obrigatoriamente usar a função Help
        Help('',1,'VldFilial',,'Filial '+cFilVld+' NÃO existe no sistema.',1)
    EndIf

Return lRet

editar
- x
grosseiro ou ofensivo pouco construtivo obsoleto outro...
Motivo

criado 02 de Jun de 2022
Cirilo Rocha
1658 pontos

0

Olá Cirilo, Obrigada seu exemplo também me deu uma base de como fazer.
— Eduarda Menezes 06 de Jun de 2022

up 0 down
User Function zEMP()

Local aArea := GetArea()

Local lRet := .T.

Local cCodFil := ""

Local cCamp := Alltrim(M->ZZH_CODEMP)

Local aSm0 := FWLoadSM0()

Local nPos := Ascan(aSM0,{|x| Alltrim(x[2]) == Alltrim(cCamp)})

IF (nPos > 0)

cCodFil := aSm0[nPos][02]

MsgAlert("Filial Existe"+cCodFil)

ELSEIF cCamp == "*"

ELSE

Help('',1,'VldFilial',,'Filial '+cCodFil+' NÃO existe no sistema.',1) lRet := .F. ENDIF

RestArea(aArea)

Return (lRet)
- editar
- x
  
  grosseiro ou ofensivo pouco construtivo obsoleto outro...
  Motivo
- criado 06 de Jun de 2022
  Eduarda Menezes
  147 pontos
Adicionar comentário

Caracteres restantes: 600
Quero acompanhar este tópico via email.

Comentário
Utilize formatação mini-Markdown: [link](http://exemplo.com) _italico_ **negrito** `codigo`.
Comentarios devem ter, no maximo, 600 caracteres. Se achar necessario, utilize links em vez de copiar código ou ainda edite sua pergunta/resposta para colocar mais informações

Validar campo função SM0 retorna Código Filial

Comentário

3 respostas

Comentário

Comentário

Comentário

Não é a resposta que estava procurando? Procure outras perguntas com as tags advpl sm0 mvc ou faça a sua própria pergunta.