Implementar Pattern Singleton em uma classe Advpl

Atualmente na linguagem ADVPL não é possível implementar o padrão de projeto Singleton, dado ao fato que é necessário que a propriedade que armazenará a instância da classe tenha escopo privado (assim como o construtor), contudo o ADVPL não possui identificadores de escopo de privem o usuário do acesso direto.

Sim! Diferente do que muitos pensam, em AdvPL, uma classe não possui um método construtor padrão; e a palavra chave Constructor serve apenas para legibilidade.

• Ao utilizar Classe():Metodo(), independente do método estar assinado como construtor, sempre é criada uma instância nova.
  • Ao utilizar obj:Metodo(), localiza-se a o protótipo da classe de objeto, então invoca-se o método com o valor de Self predefinido como a instância atual.

Podemos usar variáveis estáticas para reter uma instância de classe e implementar o New definindo a instância inicial da classe e sempre retornando-a. Situação similar acontece quando herdamos de uma classe sem sobrecarregar o New: uma instância da classe pai é retornada. Para instanciar a primeira vez, podemos usar a função WsClassNew. Nas versões recentes dos includes TOTVS, em específico, o msobject.ch, há a implementação da cláusula Static para métodos, então podemos ter singletons:

/** HERE BE DRAGONS */

#include 'protheus.ch'

Static oInstance

Class MySingleton
    Static Method New()
EndClass

Method New() Class MySingleton
    If oInstance == Nil
        oInstance := WsClassNew( 'MySingleton' )
    EndIf
Return oInstance

User Function Singleton()
    Local oInstance := MySingleton():New()
    Local oOther := MySingleton():New()
    If oInstance == oOther
        ConOut( "References are equal!" )
    Else
        ConOut( "Nope!" )
    EndIf
Return