Redimensionamento de objeto

Boa noite Ronald,

É possível fazer isso, mas você terá que obter o objeto do TSimpleEditor e também enviar um bloco de código do click no método addWindow.

Alterando a função fPanelSQL para que retorno o TSimpleEditor, dessa forma podemos utilizar do mesmo em outros pontos do código:

Static Function fPanelSQL(oPanel)
    Local oTSEditSql as object

    oTSEditSql := TSimpleEditor():New(,,oPanel,,)
    oTSEditSql:lAutoIndent := .T.
    oTSEditSql:nWidth   := oPanel:nWidth
    oTSEditSql:nHeight  := oPanel:nHeight

Return oTSEditSql

Agora, ao chamar a função fPanelSQL, vamos guardar a instância da TSimpleEditor:

oSQL := FPanelSQL(@(oLyrSQL:GetWinPane('cCONSULTA','wCONSULTA','lCONSULTA')))

Com isso, agora temos a instância da TSimpleEditor para enviar no bloco do click ao adicionar uma window:

oLyrSQL:addWindow('cCONSULTA', 'wRESULTADO','Resultado'  ,40,.T.,.T.,{||sizePnlSQL(oSQL)},'lCONSULTA',)

Por fim, criamos a função sizePnlSQL que redimensiona a altura do TSimpleEditor com base em seu parent:

static function sizePnlSQL(oSQL)
    oSQL:nHeight := oSQL:oParent:nHeight
return nil

O código final ficaria mais ou menos da seguinte forma:

#include "TOTVS.CH"

// Alinhamento do método addInLayout
#define LAYOUT_ALIGN_LEFT     1
#define LAYOUT_ALIGN_RIGHT    2
#define LAYOUT_ALIGN_HCENTER  4
#define LAYOUT_ALIGN_TOP      32
#define LAYOUT_ALIGN_BOTTOM   64
#define LAYOUT_ALIGN_VCENTER  128

// Alinhamento para preenchimento dos componentes no TLinearLayout
#define LAYOUT_LINEAR_L2R 0 // LEFT TO RIGHT
#define LAYOUT_LINEAR_R2L 1 // RIGHT TO LEFT
#define LAYOUT_LINEAR_T2B 2 // TOP TO BOTTOM
#define LAYOUT_LINEAR_B2T 3 // BOTTOM TO TOP

function u_fEstAlias()
    local oDlg as object
    local oSQL as object
    local aTam as array
    local oTBar as object
    local oBBrNovo as object
    local oBBrAbrir as object
    local oBBrPlay as object
    local oLyrSQL as object

    oDlg := TDialog():New(,,600,1000,'Consulta SQL',,,,,CLR_BLACK,CLR_WHITE,,,.T.,,,,,,)

    aTam  := FwGetDialogSize(oDlg)
    oDlg:lCentered  := .T.
    oDlg:lMaximized := .T.

    oDlg:nTop       := aTam[1]
    oDlg:nLeft      := aTam[2]
    oDlg:nBottom    := aTam[3]
    oDlg:nRight     := aTam[4]

    oDlg:nClientHeight  := aTam[3]
    oDlg:nClientWidth   := aTam[4]

    oDlg:Refresh()

    //Componentes do cabeçalho
    oTBar       := TBar():New( oDlg, 25, 32, .T.,,,, .T.)
    oBBrNovo    := TBtnBmp2():New( 00, 00, 35, 25, 'TK_NOVO',,,, { || Alert( 'Novo' ) }     , oTBar, 'Nova Consulta'    ,, .F., .F. )
    oBBrAbrir   := TBtnBmp2():New( 00, 00, 35, 25, 'OPEN'   ,,,, { || Alert( 'Abrir' ) }    , oTBar, 'Abrir Consulta'   ,, .F., .F. )
    oBBrSalvar  := TBtnBmp2():New( 00, 00, 35, 25, 'SALVAR' ,,,, { || Alert( 'Salvar' ) }   , oTBar, 'Salvar Consulta'  ,, .F., .F. )
    oBBrPlay    := TBtnBmp2():New( 00, 00, 35, 25, 'NEXT'   ,,,, { || Alert( 'Executar' ) } , oTBar, 'Executar Consulta',, .F., .F. )

    oLyrSQL := FWLayer():new()
    oLyrSQL:init(oDlg,.F.)

    oLyrSQL:addLine('lCONSULTA',100,.F.)

    oLyrSQL:addCollumn ('cCONSULTA',100,.F.,'lCONSULTA')

    oLyrSQL:addWindow('cCONSULTA', 'wCONSULTA' ,'SQL'        ,60,.F.,.F.,,'lCONSULTA',)
    oLyrSQL:addWindow('cCONSULTA', 'wRESULTADO','Resultado'  ,40,.T.,.T.,{||sizePnlSQL(oSQL)},'lCONSULTA',)

    oSQL := FPanelSQL(@(oLyrSQL:GetWinPane('cCONSULTA','wCONSULTA','lCONSULTA')))

    oDlg:Activate()
Return

Static Function fPanelSQL(oPanel)
    Local oTSEditSql as object

    oTSEditSql := TSimpleEditor():New(,,oPanel,,)
    oTSEditSql:lAutoIndent := .T.
    oTSEditSql:nWidth   := oPanel:nWidth
    oTSEditSql:nHeight  := oPanel:nHeight

Return oTSEditSql

static function sizePnlSQL(oSQL)
    oSQL:nHeight := oSQL:oParent:nHeight
return nil

https://tdn.totvs.com/display/public/PROT/FWLayer

Grande Daniel, muito obrigado pela força.