Alinhamento de TGet usando a opção SetContentAlign

Ricardo,

O nome correto do método para alinhar o conteúdo no TGet é SetContentAlign, em seu exemplo você escreveu SetGtAlign.

Abaixo um exemplo de uso:

//-------------------------------------------------------------------
/*/{Protheus.doc} alignContent
Exemplo de alinhamento de conteúdo no TGet

@author Daniel Mendes
@since Mar 11, 2022
@version 1.0
/*/
//-------------------------------------------------------------------
user function alignContent()
local oDlg as object
local cEsquerda as character
local cCentro as character
local cDireita as character
local oEsquerda as object
local oCentro as object
local oDireita as object

oDlg = TDialog():New( 0, 0, 200, 300, "Exemplo TGet com alinhamento de conteúdo",,,.F.,,,,,,.T.,,,,, )

cEsquerda := "Esquerda"
oEsquerda := TGet():New( 01, 25, {|x| Iif(PCount() > 0, cEsquerda := x, cEsquerda)}, oDlg, 096, 009,,,0,,,.F.,,.T.,,.F.,,.F.,.F.,,.F.,.F.,, cEsquerda,,,, )
oEsquerda:SetContentAlign(-1) //Deixa o alinhamento a esquerda

cCentro := "Centro"
oCentro := TGet():New( 35, 25, {|x| Iif(PCount() > 0, cCentro := x, cCentro) }, oDlg, 096, 009,,,0,,,.F.,,.T.,,.F.,,.F.,.F.,,.F.,.F.,, cCentro,,,, )
oCentro:SetContentAlign(0) //Deixa o alinhamento centralizado

cDireita := "Direta"
oDireita := TGet():New( 70, 25, {|x| Iif(PCount() > 0, cDireita := x, cDireita)}, oDlg, 096, 009,,,0,,,.F.,,.T.,,.F.,,.F.,.F.,,.F.,.F.,, cDireita,,,, )
oDireita:SetContentAlign(1) //Deixa o alinhamento a direita

oDlg:Activate(,,,.T.,,,,,)

return

Documentação: https://tdn.totvs.com/display/tec/TGet%3ASetContentAlign