Ponto de entrada MA030CLI para CRMA980

Um tempo atrás quando foi alterada a rotina para MVC eu fiz um pequeno mapeamento dos P.E. antigos para o MVC. Lembrando que nem todos os pontos de entrada antigos tem equivalência MVC. Documentação https://tdn.totvs.com/pages/releaseview.action?pageId=604230458

#INCLUDE "RWMake.ch"
#INCLUDE "Totvs.ch"
#INCLUDE "ParmType.ch"
#Include "FWMVCDef.ch"

//#############################################################################
//##+----------+----------+-------+--------------------+------+-------------+##
//##|Programa  | CRMA980  | Autor | Cirilo Rocha       | Data | 29/11/2019  |##
//##+----------+----------+-------+--------------------+------+-------------+##
//##|Descr.    | Ponto de entrada MVC do cadastro de clientes (MATA030)     |##
//##+----------+----------+-------------------------------------------------+##
//##| DATA     | ANALISTA | MANUTENÇÃO EFETUADA                             |##
//##+----------+----------+-------------------------------------------------+##
//##|          |          |                                                 |##
//##|          |          |                                                 |##
//##|          |          |                                                 |##
//##+----------+----------+-------------------------------------------------+##
//#############################################################################
User Function CRMA980()

    //Declaracao de variaveis----------------------------------------------------------------------
    Local xRet                AS Variant
    Local cIdPonto            AS Character
    Local cIdModel            AS Character
    Local lIsGrid             AS Logical
    Local nLinha             AS Numeric
    Local nQtdLinhas         AS Numeric
    Local nOper                AS Numeric

    //Privada para usar no Type()
    Private oObj            AS Object

    //Inicializa Variaveis-------------------------------------------------------------------------
    xRet             := .T.

    //---------------------------------------------------------------------------------------------
    If ParamIxb <> NIL
        oObj         := ParamIxb[1]
        cIdPonto     := ParamIxb[2]
        cIdModel     := ParamIxb[3]
        lIsGrid     := ( Len( ParamIxb ) > 3 ) .And. ValType(ParamIxb[4]) == 'N'

        If lIsGrid
            nQtdLinhas     := oObj:GetQtdLine()
        //    nLinha         := oObj:nLine
            nLinha         := ParamIxb[4]
        EndIf

        nOper    := oObj:GetOperation()

        //Chamada na validacao total do modelo-----------------------------------------------------
        If cIdPonto == 'MODELPOS' //Chama duas vezes, nao sei porque, pode usar o FORMPOS que tem a mesma funcao e chama 1 vez so

            xRet    := .T.
            If ExistBlock("MA030TOK")
                xRet    := ExecBlock("MA030TOK", .F., .F.)
            EndIf

            If     ExistBlock("VBTOK030") .And. ;
                .Not. ExecBlock("VBTOK030", .F., .F., 5 )

                xRet    := .F.
            EndIf

        //Chamada apos a gravacao total do modelo e dentro da transacao----------------------------
        ElseIf cIdPonto == 'MODELCOMMITTTS'

            If     nOper == MODEL_OPERATION_INSERT
                If ExistBlock("M030INC")
                    ExecBlock("M030INC", .F., .F., 1 )
                EndIf

                //Salvo o codigo para usar em outros fontes, as vezes ele perde a posicao quando termina
                _cCodCli    := SA1->A1_COD
            EndIf

            If     nOper == MODEL_OPERATION_UPDATE .And. ;
                ExistBlock("MALTCLI")

                ExecBlock("MALTCLI", .F., .F.)
            EndIf

            If     nOper == MODEL_OPERATION_DELETE .And. ;
                ExistBlock("M030EXC")

                ExecBlock("M030EXC", .F., .F.)
            EndIf

        //Chamada apos a gravacao total do modelo e fora da transacao------------------------------
        ElseIf cIdPonto == 'MODELCOMMITNTTS'

            If     nOper == MODEL_OPERATION_UPDATE .And. ;
                ExistBlock("M030PALT")

                xRet    := ExecBlock("M030PALT", .F., .F.,1)
            EndIf            

        //Chamada no Botão Cancelar----------------------------------------------------------------
        ElseIf cIdPonto == 'MODELCANCEL'

            If     nOper == MODEL_OPERATION_INSERT
                If ExistBlock("M030INC")
                    ExecBlock("M030INC", .F., .F.,3)
                EndIf
            EndIf

            If     nOper == MODEL_OPERATION_UPDATE .And. ;
                ExistBlock("M030PALT")

                xRet    := ExecBlock("M030PALT", .F., .F.,0)
            EndIf            

        //Chamada na validacao da ativacao do Model------------------------------------------------
        ElseIf cIdPonto == 'MODELVLDACTIVE'

            xRet    := .T.

            If     nOper == MODEL_OPERATION_INSERT .And. ;
                ExistBlock("MA030VINC")

                xRet    := ExecBlock("MA030VINC", .F., .F.)
            EndIf

            If     nOper == MODEL_OPERATION_UPDATE
                If ExistBlock("M030ALT")
                    xRet    := ExecBlock("M030ALT", .F., .F.)
                EndIf

                If ExistBlock("MT030INT")
                    .Not. ExecBlock("M030ALT", .F., .F.)

                    xRet    := .F.
                EndIf
            EndIf            

            If     nOper == MODEL_OPERATION_DELETE .And. ;
                ExistBlock("M030DEL")

                xRet    := ExecBlock("M030DEL", .F., .F.)
            EndIf            

        EndIf
    EndIf

Return xRet

Bom dia!

Não consegui encontrar informações referente ao ponto de entrada MA030CLI e sua localização, mas de qualquer maneira o cadastro de clientes em MVC possui um ponto de entrada que permite a validação em diversos momentos do formulário de cadastro. Segue exemplo básico:

User Function CRMA980
Local aParam    As Array
Local oObj      As Object
Local cIdPonto  As Character
Local cIdModel  As Character
Local xRet

    xRet     := .T.
    aParam     := PARAMIXB

    If(ValType(aParam) == 'A')

        oObj        := aParam[1]
        cIdPonto    := aParam[2]
        cIdModel    := aParam[3]

        If(cIdPonto == 'FORMPOS') // Processamento ao clicar no botão Confirmar (retorno lógico)

            If(cIdModel == 'SA1MASTER')

                If(oObj:GetOperation() == MODEL_OPERATION_UPDATE)

                    If(FwFldGet('A1_YTESTE') <> '1')

                        xRet := .F.

                        // Não irá permitir salvar o cadastro

                        Help(, , 'Dados Inválidos', , 'O campo A1_YTESTE precisa ser igual a 1.', 1, 0, , , , , , {''})

                    EndIf

                EndIf

            EndIf

        ElseIf(cIdPonto == 'MODELCOMMITTTS') // Processamento após a gravação

            If(oObj:GetOperation() == MODEL_OPERATION_INSERT)

                // Executado após incluir um cliente

            ElseIf(oObj:GetOperation() == MODEL_OPERATION_UPDATE)

                // Executado após alterar um cliente

            ElseIf(oObj:GetOperation() == MODEL_OPERATION_DELETE)

                // Executado após excluir um cliente

            EndIf

        EndIf

    EndIf

Return(xRet)

Esta documentação possui um exemplo mais completo do uso desse ponto de entrada: DT PE CRMA980 - Pontos de Entrada do Cadastro de Clientes (MVC)

Já essa documentação explica melhor o momento de execução de cada validação dentro de um ponto de entrada em MVC (antes de alterar, após alteração, após gravação, etc.): Pontos de Entrada para fontes Advpl desenvolvidos utilizando o conceito MVC

If you have joined [url=https://sites.google.com/coinbaselogiin.com/coinbaseprologin/home] Coinbase Pro Login[/url] as a beginner and now you think you have enough knowledge and skills to move on to a professional level then you can probably think of joining.[url=https://sites.google.com/coinbaselogiin.com/coinbasewallet/home]Coinbase Wallet[/url]