Se alguma pergunta ou resposta lhe foi útil, não deixe de dar seu voto positivo!
Bom dia! Eu gostaria de saber se existe alguma função ou alguma coisa que retorne o código do usuário pelo nome dele.
Estou montando um WebService e na chamada da API o parâmetro requisitado é o nome do usuário, depois dentro do WS eu precisaria de uma forma (se possível sem montar um SQL) de retornar o código do usuário informado no parâmtetro.
Victor,
Uma opção é utilizar da função FWSFAllUsers e com base em seu retorno, efetuar a busca.
Veja um exemplo de implementação:
//-------------------------------------------------------------------
/*{Protheus.doc} u_UsrByName
Busca e retorna um usuário com base no nome
@param cName Nome do usuário
@return aUser Array com os dados do usuário encontrado
@author Daniel Mendes
@since 25/06/2020
@version 1.0
*/
//-------------------------------------------------------------------
function u_UsrByName(cName)
local aUsersAux as array
local aUser as array
local nPos as numeric
aUsersAux := FWSFAllUsers(/*aUserList*/, {"USR_NOME"})
cName := Upper(AllTrim(cName))
nPos := aScan(aUsersAux, {|aUsr| Upper(AllTrim(aUsr[3])) == cName})
if nPos > 0
aUser := aClone(aUsersAux[nPos])
else
aUser := {}
endif
aSize(aUsersAux, 0)
aUsersAux := nil
return aUserCom isso basta então chamar a função u_UsrByName informando o nome do usuário:
//-------------------------------------------------------------------
/*{Protheus.doc} u_TestUsr
Teste da função u_UsrByName, responsável por retornar um
array com as informações do usuário com base em seu nome
@author Daniel Mendes
@since 25/06/2020
@version 1.0
*/
//-------------------------------------------------------------------
function u_TestUsr()
local aUser as array
rpcSetEnv("99", "01")
aUser := u_UsrByName("Daniel Mendes")
varInfo("User", aUser)
aSize(aUser, 0)
aUser := nil
aUser := u_UsrByName("Não existe")
varInfo("User", aUser)
aSize(aUser, 0)
aUser := nil
rpcClearEnv()
return nilSe desejar retornar mais dados do usuário, basta informar outros valores no array de segundo parâmetro da função FWSFAllUsers, mas manter o nome é essencial para a mesma funcionar.
Documentação: https://tdn.totvs.com/display/public/PROT/FWSFALLUSERS
Obs.: Ressalto que o nome do usuário pode ser repetido, logo a função retornará o primeiro usuário encontrado.
Obrigado pela resposta! Tinha visto sobre a FWSFAllUsers mas fiquei em dúvida se não teria alguma outra. Vou implementar essa solução aqui, obrigado!!
Para retornar o código de usuário corrente no sistema é: __cuserid
Eu precisaria usar o nome de usuário como parâmetro, __cuserid retorna o usuário corrente.
— Victor S Henrique 25 de Jun de 2020Cara você pode guardar o login e password deles de forma segura e passar nas requisições, dentro do programa protheus você então teria corretamente o __cUserId
ISSO claro usando security=1 na configuração do REST.
Acho que terá problemas com Nome.
Victor, seria o nome ou o login? Vale ressaltar que o nome pode ser repetido, você pode ter N usuários chamados Batata.
— Daniel Mendes 25 de Jun de 2020A api será consumida por usuários chaves em cada departamento, por enquanto ficou acertado que eles vão passar o nome completo como parâmetro
— Victor S Henrique 25 de Jun de 2020