Se alguma pergunta ou resposta lhe foi útil, não deixe de dar seu voto positivo!

Substituição do CriaTrab por FWTemporaryTable - sem utilizar um array de campos

Boa tarde! Alguém já realizou a substituição de um código semelhante ao abaixo por outro utilizando a classe FWTemporaryTable sem a utilização de um array com a estrutura dos campos ?

cIndex := CriaTrab(,.f.)

cCond := "E2_FILIAL='" + xFilial( "SE2" ) + "' .AND. "

cCond += "E2_FORNECE='" + cA100For + "' .AND. "

cCond += "E2_LOJA='" + cLoja + "'"

IndRegua("SE2",cIndex,"DTOS(E2_VENCREA)",, cCond,OemToAnsi(""))

nIndexSE2 := RetIndex("SE2")+1

dbSetIndex(cIndex+OrdBagExt())

Ao realizar a análise do programa no Code Analysis não foi retornado nenhum bug a respeito, mas eu gostaria de utilizar a classe FWTemporaryTable para substituir todos os "CriaTrab" de meu projeto. Como poderia ficar esse código com essa substituição?

criatrab

criado 10 de Feb de 2023
Ronaldo Zambello
6 pontos
editado 10 de Feb de 2023

Você vai ver essas setas em qualquer página de pergunta. Com elas, você pode dizer se uma pergunta ou uma resposta foram relevantes ou não.
Edite sua pergunta ou resposta caso queira alterar ou adicionar detalhes.
Caso haja alguma dúvida sobre a pergunta, adicione um comentário. O espaço de respostas deve ser utilizado apenas para responder a pergunta.
Se o autor da pergunta marcar uma resposta como solucionada, esta marca aparecerá.
Clique aqui para mais detalhes sobre o funcionamento do TOTVS DevForum!

1 resposta

Ronaldo fiz os ajustes no seu programa para converter para FWTemporaryTable().

Local aArea        AS Array
Local aFields    AS Array
Local aStruct    AS Array
Local aTamSX3    AS Array
Local cAlias    AS Character
Local cQuery    AS Character
Local cCpoQry    AS Character
Local lRet        AS Logical
Local oTable    AS Object
Local nX        AS Numeric

lRet := .F.
aArea := GetArea()

aFields := {'E2_FILIAL','E2_NUM','E2_PARCELA','E2_VENCREA'}    //Campos gerados na tabela temporária

//Monta estrutura dos campos
aStruct    := {}
cCpoQry    := ''
For nX := 1 to Len(aFields)
    aTamSX3    := TamSX3(aFields[nX])
    //            Nome_Cpo    Tipo       Tamanho     Decimal
    aAdd(aStruct,{aFields[nX],aTamSX3[3],aTamSX3[1],aTamSX3[2]})

    //Monta campos usados na query
    cCpoQry    += aFields[nX]
    If nX <> Len(aFields)
        cCpoQry    += ','
    EndIf
Next

//Cria tabela temporária
oTable := FWTemporaryTable():New()
oTable:setFields(aStruct)
oTable:addIndex("1", {"E2_VENCREA"})    //Indice 1 da tabela
oTable:create()

cAlias    := oTable:getAlias()    //Alias para uso no programa

//Faz o preenchimento da tabela via SQL
cQuery := "INSERT INTO " + oTable:getRealName()+CRLF
cQuery += "("+cCpoQry+") "+CRLF
cQuery += "SELECT "+cCpoQry+CRLF
cQuery += "FROM " + RetSqlName("SE2") + " SE2 "+CRLF
cQuery += "WHERE SE2.D_E_L_E_T_='' "+CRLF
cQuery += "    AND E2_FILIAL='" + xFilial( "SE2" ) + "' "+CRLF
cQuery += "    AND E2_FORNECE='" + cA100For + "' "+CRLF
cQuery += "    AND E2_LOJA='" + cLoja + "'"+CRLF

if TCSqlExec(cQuery) >= 0    //Conseguiu popular a tabela
    lRet    := .T.
    //...PROCESSAMENTO OU TELA...    
Else                        //ERRO na gravação da tabela
     lRet := .F.

     // Caso deseja gerar exceção...
     // UserException(TCSqlError())
EndIf

//Limpa tabela temporária
oTable:delete()
FreeObj(oTable)

RestArea(aArea)

editar
- x
grosseiro ou ofensivo pouco construtivo obsoleto outro...
Motivo

criado 10 de Feb de 2023
Cirilo Rocha
1680 pontos

Substituição do CriaTrab por FWTemporaryTable - sem utilizar um array de campos

Comentário

1 resposta

Comentário

Não é a resposta que estava procurando? Procure outras perguntas com as tags criatrab ou faça a sua própria pergunta.