Uso de Return dentro do BeginTransaction

Senhores estou com seguinte bug apontado no codeanalytics:

Abaixo segue o Trecho do código que esta retornando o bug:

If !Empty(cIntegrado)

BEGIN TRANSACTION

If !Empty(p_cNotaIni)

IncProc("Importando NF de transferencia de Medicamentos na Matriz "+_cDoc+"/"+_cSerie)

EndIf

_lOk := U_UNP015(_cDoc,_cSerie,_cChave,_dEmissao)

If !_lOk

DisarmTransaction()

Return

EndIf

If !Empty(p_cNotaIni)

IncProc("Gerando Pedido de Venda do Integrado...")

EndIf

cNumPedido := U_LHC16(_cDoc,_cSerie)

If Empty(cNumPedido)

DisarmTransaction()

Alert(OemToAnsi("LHC16 - Erro na Inclusão do Pedido referente a NF de transferência " + _cSerie + "/" + _cDoc))

Return

EndIf

END TRANSACTION

Como posso fazer para matar esse problema? Alguem com algo parecido?

advpl

criado 25 de May de 2023
Luis Christo
61 pontos
editado 25 de May de 2023

Você vai ver essas setas em qualquer página de pergunta. Com elas, você pode dizer se uma pergunta ou uma resposta foram relevantes ou não.
Edite sua pergunta ou resposta caso queira alterar ou adicionar detalhes.
Caso haja alguma dúvida sobre a pergunta, adicione um comentário. O espaço de respostas deve ser utilizado apenas para responder a pergunta.
Se o autor da pergunta marcar uma resposta como solucionada, esta marca aparecerá.
Clique aqui para mais detalhes sobre o funcionamento do TOTVS DevForum!

1 resposta

up 1 down
Olá Luis,

A utilização de mensagens e retornos dentro de transação não é considerada uma boa prática, já tivemos situações do return ser antes do End Transaction e gerar problemas, assim como já tivemos mensagens que seguraram a transação levando a um dead lock generalizado na rotina.

Essas experiências nos ensinaram bastante a evitar esse tipo de código.

Um exemplo do seu código, seria o seguinte:
```
Local cMsgError as character

If !Empty(cIntegrado)

    BEGIN TRANSACTION

        If !Empty(p_cNotaIni)
            IncProc("Importando NF de transferencia de Medicamentos na Matriz "+_cDoc+"/"+_cSerie)
        EndIf

        _lOk := U_UNP015(_cDoc,_cSerie,_cChave,_dEmissao)

        If _lOk
            If !Empty(p_cNotaIni)
                IncProc("Gerando Pedido de Venda do Integrado...")
            EndIf

            cNumPedido := U_LHC16(_cDoc,_cSerie)

            If Empty(cNumPedido)
                DisarmTransaction()
                cMsgError := OemToAnsi("LHC16 - Erro na Inclusão do Pedido referente a NF de transferência " + _cSerie + "/" + _cDoc)
            EndIf
        Else
            DisarmTransaction()
        EndIf

    END TRANSACTION

EndIf

If !Empty(cMsgError)
    Alert(cMsgError)
EndIf
```
Acredito que deseja forma, o código terá o mesmo comportamento, mas respeitando as boas práticas adotadas pelo SonarQube.
- editar
- x
  
  grosseiro ou ofensivo pouco construtivo obsoleto outro...
  Motivo
- criado 25 de May de 2023
  Daniel Mendes
  15889 pontos
Adicionar comentário

Caracteres restantes: 600
Quero acompanhar este tópico via email.

Comentário
Utilize formatação mini-Markdown: [link](http://exemplo.com) _italico_ **negrito** `codigo`.
Comentarios devem ter, no maximo, 600 caracteres. Se achar necessario, utilize links em vez de copiar código ou ainda edite sua pergunta/resposta para colocar mais informações

Uso de Return dentro do BeginTransaction

Comentário

1 resposta

Comentário

Não é a resposta que estava procurando? Procure outras perguntas com as tags advpl ou faça a sua própria pergunta.