Metodo SayAlign - FWMsPrinter

Boa noite Rubens,

O método SayAlign recebe como quinto parâmetro (nWidth) o tamanho horizontal do texto, com base nesse valor que o texto é impresso:

https://tdn.totvs.com/display/public/mp/FWMsPrinter

Para calcular o tamanho do texto, você pode utilizar o método GetTextWidth da própria FWMSPrinter.

Abaixo o seu exemplo com as alterações necessárias para que o método SayAlign funcione corretamente:

#INCLUDE "totvs.ch"
#INCLUDE "fwprintsetup.ch"
#INCLUDE "rptdef.ch"

//--------------------------------------------------------------
/*/{Protheus.doc} TstSayAlign
Teste de utilização do método SayAlign d classe FWMSPrinter

@sample U_TstSayAlign
@since 13/09/2019
@version 1.0
/*/
//--------------------------------------------------------------
user function TstSayAlign()
local cRelName as char
local lAdjust as logical
local nPrintType as numeric
local oFont10 as object
local oPrinter as object
local cText as char
local nSize as numeric

cRelName   := "TSTMSPRINT"
lAdjust    := .F.
nPrintType := 6
oFont10    := TFont():New("ARIAL",10,10,,.F.,,,,,.F.,.F.) ///Fonte 10 Normal

oPrinter := FWMSPrinter():New(cRelName, nPrintType, lAdjust, "/SPOOL/", .T., /*lTReport*/ ,/* oPrintSetup */,/*cPrinter*/, .t. )
oPrinter:SetPortrait()
oPrinter:SetPaperSize(DMPAPER_A4)
oPrinter:setCopies(1)

nCenterPg := Round(oPrinter:nHorzSize() / 2 ,0)

oPrinter:StartPage() // Inicia uma nova pagina

nLin := 25
oPrinter:Say( nlin,nCenterPg,"Texto para visualização",oFont10 )
nLin += 25

cText := "Texto para visualização SayAlign"

//Necessário calcular o tamanho da string que será impressa
nSize := oPrinter:GetTextWidth(cText, oFont10)

oPrinter:SayAlign(nLin, nCenterPg, cText, oFont10, nSize, ,CLR_BLACK , 0, 1)
nLin += 25
oPrinter:SayAlign(nLin, nCenterPg, cText, oFont10, nSize, ,CLR_BLACK , 0, 1) //oPrinter:SayAlign(nLin, nCenterPg, cText, oFont10, nSize, ,CLR_BLACK , 1, 1)
nLin += 25
oPrinter:SayAlign(nLin, nCenterPg, cText, oFont10, nSize, ,CLR_BLACK , 2, 1)

oPrinter:EndPage()
oPrinter:Preview()

return nil